我正在尝试在Fiori Elements列表报表的对象页面中添加一个表格。

该报表的主数据源是下方的视图 ZC_BUSINESS_PARTNER。

我想添加的表格应该包含来自Bank关联的条目。

“Banks” 部分未出现。

@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Business Partners report'
@Metadata.ignorePropagatedAnnotations: true
@OData.publish: true
@UI.headerInfo: { typeName: 'BusinessPartner', imageUrl: 'BusinessPartnerImageURL', title: { value: 'BusinessPartnerName', type: #STANDARD }, description: { value: 'BusinessPartner', type: #STANDARD } }

define root view entity ZC_BUSINESS_PARTNER as select from I_BusinessPartner
  composition [0..*] of ZC_BUSINESS_PARTNER_BANK    as _Bank
  association [0..1] to I_BusinessPartnerGrouping   as _BusinessPartnerGrouping     on $projection.BusinessPartnerGrouping  = _BusinessPartnerGrouping.BusinessPartnerGrouping
{
  @ui.facet: [
    {
        id: 'Info',
        type: #FIELDGROUP_REFERENCE,
        position: 10,
        purpose: #HEADER,
        targetQualifier: 'Info'
    },
    {
        id: 'Addr',
        label: 'Address',
        type: #FIELDGROUP_REFERENCE,
        position: 20,
        purpose: #HEADER,
        targetQualifier: 'Address'
    },
    {
        id: 'Contact',
        label: 'Contact',
        type: #FIELDGROUP_REFERENCE,
        position: 30,
        purpose: #HEADER,
        targetQualifier: 'Contact'
    },
    {
        id: 'Bank',
        label: 'Banks',
        type: #LINEITEM_REFERENCE,
        position: 10,
        targetQualifier: 'Bank',
        targetElement: '_Bank'
     }
  ]

  @ui.lineItem: [{ position: 10 }]
  @ui.selectionField: [{position: 10}]
  @ui.textArrangement: #TEXT_SEPARATE
  @search.defaultSearchElement: true
  @search.fuzzinessThreshold: 0.8
  @search.ranking: #HIGH
  key I_BusinessPartner.BusinessPartner,

  @ObjectModel.readOnly: true
  @ObjectModel.virtualElement
  @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MD_BP_ROOT_CALC_EXIT'
  cast( '' as abap.sstring( 260 ) )                                          as BusinessPartnerImageURL,

  [...]

  _Bank

}

视图 ZC_BUSINESS_PARTNER_BANK：

@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Business Partners Bank'
@Metadata.ignorePropagatedAnnotations: true
define view entity ZC_BUSINESS_PARTNER_BANK as select from I_BusinessPartnerBank
  association to parent ZC_BUSINESS_PARTNER as _BusinessPartner on $projection.BusinessPartner = _BusinessPartner.BusinessPartner
{
@UI.lineItem: [{ position: 10, qualifier: 'Bank'}]
key BusinessPartner,
@UI.lineItem: [{ position: 20, qualifier: 'Bank'}]
key BankIdentification,
@UI.lineItem: [{ position: 30, qualifier: 'Bank'}]
BankCountryKey,
@UI.lineItem: [{ position: 40, qualifier: 'Bank'}]
BankName,
@UI.lineItem: [{ position: 50, qualifier: 'Bank'}]
BankNumber,
@UI.lineItem: [{ position: 60, qualifier: 'Bank'}]
SWIFTCode,
@UI.lineItem: [{ position: 70, qualifier: 'Bank'}]
BankControlKey,
@UI.lineItem: [{ position: 80, qualifier: 'Bank'}]
BankAccountHolderName,

[...]

/* Associations */
_Bank,
_BusinessPartner,
_BusinessPartnerBankAlias,
_IBAN
}

欢迎任何建议。

解决方案

在BAS / WebIDE项目中，必须删除注释文件，然后将该项目重新部署到系统。随后注释被刷新。