我有两个独立的表：

Data表包含列 [Label]（文本）、[Year]（整数）、[Location]（文本）、[Value]（整数）。

Label_List表包含列 [Label]（文本）。这是在Data表中出现的 [Label] 列的不同取值的列表。

在Data表中，每个 [Label] 可能对应多年的数据以及多个地点的记录。

我从切片器中选中了Label_List[Label] 的一个值。

在可视化中，我想把每个 [Label]（一行）与切片器所选的 [Label] 进行比较。我在逐行计算并显示每个 [Label] 行的 [Value] 平均值时遇到了困难，必须仅使用与切片器所选 [Label] 的 [Year] 与 [Location] 的组合相重叠（匹配）的 [Value] 值子集。这就是可视化示例表中的“Label Average Overlap”。

我在为另一个重叠列编写代码方面已经取得成功。举例：``` Selected Label Average Overlap = CALCULATE( AVERAGE(Data[Value]), Data[Label] = SELECTEDVALUE(Label_List[Label]), Data[Year] IN VALUES(Data[Year]) && Data[Location] IN VALUES(Data[Location]) )

我在为“Label Average Overlap” 编写代码时遇到了困难。```
Label Average Overlap = 

VAR SlicerLabel = SELECTEDVALUE(Label_List[Label])
VAR DataLabelRow = SELECTEDVALUE(Data[Label]) 

VAR CommonYearsAndLocations =
    CALCULATETABLE(
        VALUES(Data[Year]),
        FILTER(
            Data,
            COUNTROWS(
                FILTER(Data, Data[Year] = EARLIER(Data[Year]) && Data[Location] = EARLIER(Data[Location]) && Data[Label] = DataLabelRow)
            ) > 0 &&
            COUNTROWS(
                FILTER(Data, Data[Year] = EARLIER(Data[Year]) && Data[Location] = EARLIER(Data[Location]) && Data[Parent] = SlicerLabel)
            ) > 0
        )
    )

RETURN
    CALCULATE(
        AVERAGE(Data[Value]),
        Data[Label] = SlicerLabel,
        Data[Year] IN CommonYearsAndLocations,
        Data[Location] IN VALUES(Data[Location]) 
    )

Label_List表

Data表

表格可视化：示例中在切片器中选择了标签A。所有值都与标签A 进行比较。

解决方案

Label Average Overlap = 

VAR SlicerLabel =
    SELECTEDVALUE (Label_List[Label])

VAR CurrentLabel =
    SELECTEDVALUE (Data[Label])

VAR SlicerPairs =
    CALCULATETABLE (
        SUMMARIZE (Data, Data[Year], Data[Location]),
        Data[Label] = SlicerLabel
    )

VAR RowLabelPairs =
    CALCULATETABLE (
        SUMMARIZE (Data, Data[Year], Data[Location]),
        Data[Label] = CurrentLabel
    )

VAR OverlapPairs =
    INTERSECT (SlicerPairs, RowLabelPairs)

RETURN
    IF(
        ISEMPTY(OverlapPairs),
        BLANK(),
        CALCULATE (
            AVERAGE (Data[Value]),
            KEEPFILTERS (OverlapPairs),
            Data[Label] = CurrentLabel
        )
    )